Sub ZeichenGroesseAendern(Punkt as double)
   ' Autor: Klaus Reiser
   ' Ergänzung: Matthias Tacke
   ' Idee: Andreas Borutta
   Dim doc, selektion, textStueck as Object
   dim ch as double
   dim i as integer
   doc = thisComponent
   selektion = doc.getCurrentSelection()
   for i = 0 to selektion.getCount()-1
     Dim cursor as Object
     textStueck = selektion.getByIndex( i )
     cursor = doc.Text.createTextCursorByRange( textStueck )
     ch = cursor.CharHeight
     if ch = 0 then
       msgbox "Bitte verschiedene Schriftgrößen einzeln auswählen"
       exit sub
     end if
     textStueck.CharHeight = ch + Punkt
   next i
End Sub

Sub ZeichenKleiner1pt ' Für die Funktion dieses Makros ist das Makro ZeichenGroesseAendern notwendig
   ' In der folgenden Codezeile die gewünschte Schrittweite mit dem entsprechenden Vorzeichen angeben
   ' Auch gebrochene Angaben wie "- 1.5" oder "- 2.5" sind möglich
   ZeichenGroesseAendern( -1 )
End Sub

Sub ZeichenGroesser1pt ' Für die Funktion dieses Makros ist das Makro ZeichenGroesseAendern notwendig
   ' In der folgenden Codezeile die gewünschte Schrittweite mit dem entsprechenden Vorzeichen angeben
   ' Auch gebrochene Angaben wie "+ 1.5" oder "+ 2.5" sind möglich
   ZeichenGroesseAendern( +1 )
End Sub